magnum/src/Magnum/SceneTools/CMakeLists.txt

#
#   This file is part of Magnum.
#
#   Copyright © 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2019,
#               2020, 2021, 2022, 2023, 2024
#             Vladimír Vondruš <mosra@centrum.cz>
#
#   Permission is hereby granted, free of charge, to any person obtaining a
#   copy of this software and associated documentation files (the "Software"),
#   to deal in the Software without restriction, including without limitation
#   the rights to use, copy, modify, merge, publish, distribute, sublicense,
#   and/or sell copies of the Software, and to permit persons to whom the
#   Software is furnished to do so, subject to the following conditions:
#
#   The above copyright notice and this permission notice shall be included
#   in all copies or substantial portions of the Software.
#
#   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
#   IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
#   FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
#   THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
#   LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
#   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
#   DEALINGS IN THE SOFTWARE.
#

# IDE folder in VS, Xcode etc. CMake 3.12+, older versions have only the FOLDER
# property that would have to be set on each target separately.
set(CMAKE_FOLDER "Magnum/SceneTools")

# Somehow, due to MagnumTradeObjects having target_include_directories() with
# $<TARGET_PROPERTY:Corrade::PluginManager,INTERFACE_INCLUDE_DIRECTORIES>,
# if MAGNUM_SCENECONVERTER_STATIC_PLUGINS is non-empty then CMake fails with
#
#   Target "Corrade::PluginManager" not found.
#
# unless the find_package() is here. Not sure why, probably some bug in CMake
# dependency handling? Changing target_include_directories() to PRIVATE doesn't
# help, removing it altogether helps.
find_package(Corrade REQUIRED PluginManager)

# Files shared between main library and unit test library
set(MagnumSceneTools_SRCS )

# Files compiled with different flags for main library and unit test library
set(MagnumSceneTools_GracefulAssert_SRCS
    Combine.cpp
    Copy.cpp
    Filter.cpp
    Hierarchy.cpp
    Map.cpp)

set(MagnumSceneTools_HEADERS
    Combine.h
    Filter.h
    Hierarchy.h
    Map.h

    visibility.h)

set(MagnumSceneTools_PRIVATE_HEADERS
    Implementation/combine.h
    Implementation/convertToSingleFunctionObjects.h
    Implementation/sceneConverterUtilities.h)

if(MAGNUM_BUILD_DEPRECATED)
    list(APPEND MagnumSceneTools_GracefulAssert_SRCS FlattenMeshHierarchy.cpp)
    list(APPEND MagnumSceneTools_HEADERS
        FlattenMeshHierarchy.h
        FlattenTransformationHierarchy.h
        OrderClusterParents.h)
endif()

# # Objects shared between main and test library
# add_library(MagnumSceneToolsObjects OBJECT
#     ${MagnumSceneTools_SRCS}
#     ${MagnumSceneTools_HEADERS}
#     ${MagnumSceneTools_PRIVATE_HEADERS})
# target_include_directories(MagnumSceneToolsObjects PUBLIC $<TARGET_PROPERTY:Magnum,INTERFACE_INCLUDE_DIRECTORIES>)
# if(NOT MAGNUM_BUILD_STATIC)
#     target_compile_definitions(MagnumSceneToolsObjects PRIVATE "MagnumSceneToolsObjects_EXPORTS")
# endif()
# if(NOT MAGNUM_BUILD_STATIC OR MAGNUM_BUILD_STATIC_PIC)
#     set_target_properties(MagnumSceneToolsObjects PROPERTIES POSITION_INDEPENDENT_CODE ON)
# endif()

# Main SceneTools library
add_library(MagnumSceneTools ${SHARED_OR_STATIC}
    # $<TARGET_OBJECTS:MagnumSceneToolsObjects>
    ${MagnumSceneTools_GracefulAssert_SRCS}
    ${MagnumSceneTools_HEADERS}
    ${MagnumSceneTools_PRIVATE_HEADERS})
set_target_properties(MagnumSceneTools PROPERTIES DEBUG_POSTFIX "-d")
if(NOT MAGNUM_BUILD_STATIC)
    set_target_properties(MagnumSceneTools PROPERTIES VERSION ${MAGNUM_LIBRARY_VERSION} SOVERSION ${MAGNUM_LIBRARY_SOVERSION})
elseif(MAGNUM_BUILD_STATIC_PIC)
    set_target_properties(MagnumSceneTools PROPERTIES POSITION_INDEPENDENT_CODE ON)
endif()
target_link_libraries(MagnumSceneTools PUBLIC
    Magnum
    MagnumTrade)

install(TARGETS MagnumSceneTools
    RUNTIME DESTINATION ${MAGNUM_BINARY_INSTALL_DIR}
    LIBRARY DESTINATION ${MAGNUM_LIBRARY_INSTALL_DIR}
    ARCHIVE DESTINATION ${MAGNUM_LIBRARY_INSTALL_DIR})
install(FILES ${MagnumSceneTools_HEADERS} DESTINATION ${MAGNUM_INCLUDE_INSTALL_DIR}/SceneTools)

if(MAGNUM_WITH_SCENECONVERTER)
    find_package(Corrade REQUIRED Main)

    add_executable(magnum-sceneconverter sceneconverter.cpp)
    target_link_libraries(magnum-sceneconverter PRIVATE
        Corrade::Main
        Magnum
        MagnumMaterialTools
        MagnumMeshTools
        MagnumSceneTools
        MagnumTrade
        ${MAGNUM_SCENECONVERTER_STATIC_PLUGINS})

    install(TARGETS magnum-sceneconverter DESTINATION ${MAGNUM_BINARY_INSTALL_DIR})

    # Magnum sceneconverter target alias for superprojects
    add_executable(Magnum::sceneconverter ALIAS magnum-sceneconverter)
endif()

if(MAGNUM_BUILD_TESTS)
    # Library with graceful assert for testing
    add_library(MagnumSceneToolsTestLib ${SHARED_OR_STATIC} ${EXCLUDE_FROM_ALL_IF_TEST_TARGET}
        # $<TARGET_OBJECTS:MagnumSceneToolsObjects>
        ${MagnumSceneTools_GracefulAssert_SRCS})
    set_target_properties(MagnumSceneToolsTestLib PROPERTIES DEBUG_POSTFIX "-d")
    target_compile_definitions(MagnumSceneToolsTestLib PRIVATE
        "CORRADE_GRACEFUL_ASSERT" "MagnumSceneTools_EXPORTS")
    if(MAGNUM_BUILD_STATIC_PIC)
        set_target_properties(MagnumSceneToolsTestLib PROPERTIES POSITION_INDEPENDENT_CODE ON)
    endif()
    target_link_libraries(MagnumSceneToolsTestLib PUBLIC
        Magnum
        MagnumTrade)

    add_subdirectory(Test ${EXCLUDE_FROM_ALL_IF_TEST_TARGET})
endif()

# Magnum SceneTools target alias for superprojects
add_library(Magnum::SceneTools ALIAS MagnumSceneTools)